10   '
20   '    ANALYSIS OF MEASUREMENTS FROM BUBBLE 
30   '            CHAMBER PHOTOGRAPHS
40   '
50   '---------------- 1/5/88 --------------------
60   '
70   '    This program analyzes measurements made on
80   '    a series of bubble chamber photographs.
90   '    Using measurements made of the charged particle
100  '    tracks, the program computes the mass of an 
110  '    unseen neutral particle X, which is present
120  '    in sigma decay.
130  '
140  '       --> LIST OF PROCEDURES <--
150  '
160        GOSUB 250  ' INPUT
170        GOSUB 430  ' CALCULATION OF X MASS
180        GOSUB 830  ' OUTPUT
190  '
200        PRINT
210        INPUT "WANT TO RUN ANOTHER (Y/N)? ", AGAIN$
220        IF AGAIN$ = "Y" OR AGAIN$ = "y" THEN 160
230        END
240  '------------------------------------------------------
250  'INPUT
260  '
270  CLS
280  PRINT "INPUT VALUES FOR:"
290  PRINT
300  PRINT "     THE EVENT NUMBER: N"
310  PRINT "   SIGMA TRACK LENGTH: LSIG"
320  PRINT "                THETA: TH"
330  PRINT "    SAGITTA OF THE PI: S"
340  PRINT "   CHORD LENGTH OF PI: LPI"
350  PRINT
360  PRINT "SEPARATE THE INPUT VALUES WITH COMMAS AND"
370  PRINT " THEN PRESS RETURN"
380  PRINT
390  INPUT N,LSIG,TH,S,LPI
400  '
410  RETURN
420  '------------------------------------------------------
430  'CALCULATION OF X MASS
440  '
450  '
460  ' -- convert theta from degrees to radians
470  '
480  THETA = TH * 3.14159265# / 180
490  '
500  ' -- R is the radius of curvature of the PI-minus track
510  '
520  R = LPI ^ 2 / (8 * S) + S / 2
530  '
540  ' -- PPI is the momentum in MEV/C of the PI-minus track
550  '
560  PPI = 6.86 * R
570  '
580  ' -- EPI is the total relativistic energy of the
     '    PI-minus
590  '
600  EPI =  SQR (PPI ^ 2 + 140 ^ 2)
610  '
620  '-- the longest possible sigma track lenght is 0.597 cm
630  '
640  IF LSIG > .597 THEN  LET LSIG = .597
650  '
660  '-- compute sigma momentum from track lenght
670  '
680  PSIG = 174 * (1 - LSIG / .597) ^ .25
690  '
700  '--ESIG = total relativistic energy of the sigma minus
710  '
720  ESIG =  SQR (PSIG ^ 2 + 1197 ^ 2)
730  '
740  '-- compute the mass of the X particle
750  '
760  XSQ = (ESIG - EPI) ^ 2 - PSIG ^ 2 - PPI ^ 2 
770  XSQ =   XSQ + 2 * PSIG * PPI * COS (THETA)
780  X = SQR (XSQ)
790  MXP = INT ((X + .05) * 10) / 10
800  '
810  RETURN
820  '------------------------------------------------------
830  'OUTPUT
840  '
850  PRINT
860  INPUT "PRINTER (Y/N)? ",ANS$
870  PRINT
880  IF ANS$ = "Y" OR ANS$ = "y" THEN OPEN "LPT1:" FOR OUT@+
         +@PUT AS #1
890  IF ANS$ <> "Y" AND ANS$ <> "y" THEN OPEN "SCRN:" FOR @+
         +@OUTPUT AS #1
900  '
910  PRINT #1,"          EVENT NUMBER = ";N
920  PRINT #1,"    SIGMA TRACK LENGTH = ";LSIG
930  PRINT #1,"                 THETA = ";TH
940  PRINT #1,"         SAGITTA OF PI = ";S
950  PRINT #1,"    CHORD LENGTH OF PI = ";LPI
960  PRINT #1,
970  PRINT #1,"MASS OF THE X PARTICLE = "; MXP
980  '
990  CLOSE #1
1000 '
1010 RETURN
1020 '------------- END OF PROGRAM LINES -------------------